dTest package

A subpackage for FusionAtlas v0.
May 20, 2008, Noah Snyder

Introduction

This package tests whether the global dimension of the even part of a fusion graph is a d-number in the sense of Ostrik.

Implementation

Start of package

Specify package dependencies:

BeginPackage["FusionAtlas`dTest`",{"FusionAtlas`","FusionAtlas`Bigraphs`"}~Join~If[$VersionNumber<6,{"NumberTheory`AlgebraicNumberFields`"},{}]];

Usage messages

DTest::usage="";

Internals

Begin["`Private`"];

AIPolynomial[p_,x_,i_Integer]:=
CoefficientList[p,x][[Length[CoefficientList[p,x]]-i]]

Divides[a_,b_]:=Mod[b,a]==0

dPolynomialQ[p_,x_]:=With[{deg=Length[CoefficientList[p,x]]-1},
And@@Table[Divides[AIPolynomial[p,x,deg]^i,AIPolynomial[p,x,i]^deg],{i,1,deg}]]

dNumberQ[z_]:=Module[{x},dPolynomialQ[MinimalPolynomial[z,x],x]]

DTest[g_GradedBigraph]:=dNumberQ[GlobalEvenDimension[g]]

End

End[];

End of package

EndPackage[];